Vorislik va interfeyslar

Public Class Hayvon
    Public Property Nom As String

    Public Sub New(nom As String)
        Me.Nom = nom
    End Sub

    Public Sub Yurish()
        Console.WriteLine($"{Nom} yuryapti")
    End Sub
End Class

Public Class It
    Inherits Hayvon

    Public Sub New(nom As String)
        MyBase.New(nom)
    End Sub

    Public Sub Hurish()
        Console.WriteLine($"{Nom}: Vov-vov!")
    End Sub
End Class

Module Dastur
    Sub Main()
        Dim it As New It("Boryi")
        it.Yurish()
        it.Hurish()
    End Sub
End Module

Public Class Hayvon
    Public Property Nom As String

    Public Sub New(nom As String)
        Me.Nom = nom
    End Sub

    Public Overridable Sub Ovoz()
        Console.WriteLine($"{Nom} qandaydir ovoz chiqardi")
    End Sub
End Class

Public Class It
    Inherits Hayvon

    Public Sub New(nom As String)
        MyBase.New(nom)
    End Sub

    Public Overrides Sub Ovoz()
        Console.WriteLine($"{Nom}: Vov-vov!")
    End Sub
End Class

Public Class Mushuk
    Inherits Hayvon

    Public Sub New(nom As String)
        MyBase.New(nom)
    End Sub

    Public Overrides Sub Ovoz()
        Console.WriteLine($"{Nom}: Miyov!")
    End Sub
End Class

Module Dastur
    Sub Main()
        Dim hayvonlar As New List(Of Hayvon) From {
            New It("Boryi"), New Mushuk("Mosh"), New Hayvon("Noma'lum")
        }

        For Each h As Hayvon In hayvonlar
            h.Ovoz()
        Next
    End Sub
End Module

Public Class Xodim
    Public Property Ism As String
    Public Property Maosh As Decimal

    Public Sub New(ism As String, maosh As Decimal)
        Me.Ism = ism
        Me.Maosh = maosh
    End Sub

    Public Overridable Function Tavsif() As String
        Return $"{Ism}, maosh: {Maosh}"
    End Function
End Class

Public Class Boshliq
    Inherits Xodim

    Public Property Bolim As String

    Public Sub New(ism As String, maosh As Decimal, bolim As String)
        MyBase.New(ism, maosh)
        Me.Bolim = bolim
    End Sub

    Public Overrides Function Tavsif() As String
        Return MyBase.Tavsif() & $", {Bolim} bo'limi boshlig'i"
    End Function
End Class

Module Dastur
    Sub Main()
        Dim b As New Boshliq("Karimov", 12000000D, "Savdo")
        Console.WriteLine(b.Tavsif())
    End Sub
End Module

Public MustInherit Class Shakl
    Public Property Nom As String

    Public Sub New(nom As String)
        Me.Nom = nom
    End Sub

    Public MustOverride Function Yuza() As Double

    Public Sub Korsat()
        Console.WriteLine($"{Nom} yuzasi: {Math.Round(Yuza(), 2)}")
    End Sub
End Class

Public Class Aylana
    Inherits Shakl

    Private _radius As Double

    Public Sub New(radius As Double)
        MyBase.New("Aylana")
        _radius = radius
    End Sub

    Public Overrides Function Yuza() As Double
        Return Math.PI * _radius * _radius
    End Function
End Class

Public Class Torburchak
    Inherits Shakl

    Private _a As Double
    Private _b As Double

    Public Sub New(a As Double, b As Double)
        MyBase.New("To'rtburchak")
        _a = a
        _b = b
    End Sub

    Public Overrides Function Yuza() As Double
        Return _a * _b
    End Function
End Class

Module Dastur
    Sub Main()
        Dim shakllar As New List(Of Shakl) From {
            New Aylana(3), New Torburchak(4, 5)
        }

        For Each s As Shakl In shakllar
            s.Korsat()
        Next
    End Sub
End Module

Public Interface ISaqlanadigan
    Function Saqlash() As String
    ReadOnly Property Nomi As String
End Interface

Public Class Hujjat
    Implements ISaqlanadigan

    Private _nom As String

    Public Sub New(nom As String)
        _nom = nom
    End Sub

    Public ReadOnly Property Nomi As String Implements ISaqlanadigan.Nomi
        Get
            Return _nom
        End Get
    End Property

    Public Function Saqlash() As String Implements ISaqlanadigan.Saqlash
        Return $"{_nom} diskka yozildi"
    End Function
End Class

Public Class Rasm
    Implements ISaqlanadigan

    Public ReadOnly Property Nomi As String Implements ISaqlanadigan.Nomi
        Get
            Return "rasm.png"
        End Get
    End Property

    Public Function Saqlash() As String Implements ISaqlanadigan.Saqlash
        Return "Rasm siqilib saqlandi"
    End Function
End Class

Module Dastur
    Sub Main()
        Dim narsalar As New List(Of ISaqlanadigan) From {
            New Hujjat("hisobot.docx"), New Rasm()
        }

        For Each n As ISaqlanadigan In narsalar
            Console.WriteLine($"{n.Nomi}: {n.Saqlash()}")
        Next
    End Sub
End Module

Public Interface IChizilodigan
    Sub Chizish()
End Interface

Public Interface IOlchanadigan
    Function Yuza() As Double
End Interface

Public Class Kvadrat
    Implements IChizilodigan, IOlchanadigan

    Private _tomon As Double

    Public Sub New(tomon As Double)
        _tomon = tomon
    End Sub

    Public Sub Chizish() Implements IChizilodigan.Chizish
        Console.WriteLine($"Tomoni {_tomon} bo'lgan kvadrat chizildi")
    End Sub

    Public Function Yuza() As Double Implements IOlchanadigan.Yuza
        Return _tomon * _tomon
    End Function
End Class

Module Dastur
    Sub Main()
        Dim k As New Kvadrat(4)
        k.Chizish()
        Console.WriteLine(k.Yuza())
    End Sub
End Module

Public MustInherit Class Hayvon
    Public MustOverride Sub Ovoz()
End Class

Public Class It
    Inherits Hayvon
    Public Overrides Sub Ovoz()
        Console.WriteLine("Vov!")
    End Sub
    Public Sub Qorovullik()
        Console.WriteLine("It hovlini qo'riqlayapti")
    End Sub
End Class

Public Class Mushuk
    Inherits Hayvon
    Public Overrides Sub Ovoz()
        Console.WriteLine("Miyov!")
    End Sub
End Class

Module Dastur
    Sub Main()
        Dim hayvonlar As New List(Of Hayvon) From {New It(), New Mushuk()}

        For Each h As Hayvon In hayvonlar
            h.Ovoz()

            If TypeOf h Is It Then
                Dim it As It = DirectCast(h, It)
                it.Qorovullik()
            End If
        Next

        Dim birinchi As Hayvon = hayvonlar(0)
        Dim sinov As Mushuk = TryCast(birinchi, Mushuk)
        Console.WriteLine(sinov Is Nothing)
    End Sub
End Module