Sinflar va obyektlar

Public Class Talaba
    Public Property Ism As String
    Public Property Yosh As Integer
    Public Property Ball As Integer
End Class

Module Dastur
    Sub Main()
        Dim t As New Talaba()
        t.Ism = "Malika"
        t.Yosh = 22
        t.Ball = 88

        Console.WriteLine($"{t.Ism}, {t.Yosh} yosh, {t.Ball} ball")
    End Sub
End Module

Public Class Talaba
    Public Property Ism As String
    Public Property Yosh As Integer

    Public Sub New(ism As String, yosh As Integer)
        Me.Ism = ism
        Me.Yosh = yosh
    End Sub
End Class

Module Dastur
    Sub Main()
        Dim a As New Talaba("Nodira", 21)
        Dim b As New Talaba("Husanboy", 25)

        Console.WriteLine($"{a.Ism} - {a.Yosh}")
        Console.WriteLine($"{b.Ism} - {b.Yosh}")
    End Sub
End Module

Public Class Kitob
    Public Property Nom As String
    Public Property Muallif As String
    Public Property Yil As Integer

    Public Sub New(nom As String)
        Me.New(nom, "noma'lum", 0)
    End Sub

    Public Sub New(nom As String, muallif As String, yil As Integer)
        Me.Nom = nom
        Me.Muallif = muallif
        Me.Yil = yil
    End Sub
End Class

Module Dastur
    Sub Main()
        Dim k1 As New Kitob("O'tkan kunlar", "Abdulla Qodiriy", 1926)
        Dim k2 As New Kitob("Daftar")

        Console.WriteLine($"{k1.Nom} / {k1.Muallif} / {k1.Yil}")
        Console.WriteLine($"{k2.Nom} / {k2.Muallif} / {k2.Yil}")
    End Sub
End Module

Public Class Hisob
    Public Property Egasi As String
    Private _qoldiq As Decimal

    Public Sub New(egasi As String, boshlangich As Decimal)
        Me.Egasi = egasi
        _qoldiq = boshlangich
    End Sub

    Public Sub Qoshish(summa As Decimal)
        If summa <= 0 Then
            Console.WriteLine("Summa musbat bo'lishi kerak")
            Exit Sub
        End If
        _qoldiq += summa
    End Sub

    Public Function Yechish(summa As Decimal) As Boolean
        If summa > _qoldiq Then
            Return False
        End If
        _qoldiq -= summa
        Return True
    End Function

    Public Function Qoldiq() As Decimal
        Return _qoldiq
    End Function
End Class

Module Dastur
    Sub Main()
        Dim h As New Hisob("Husanboy", 500000D)

        h.Qoshish(250000D)
        Console.WriteLine(h.Qoldiq())

        Console.WriteLine(h.Yechish(100000D))
        Console.WriteLine(h.Yechish(9000000D))
        Console.WriteLine(h.Qoldiq())

        h.Qoshish(-5)
    End Sub
End Module

Public Class Mahsulot
    Private _narx As Decimal

    Public Property Narx As Decimal
        Get
            Return _narx
        End Get
        Set(qiymat As Decimal)
            If qiymat < 0 Then
                _narx = 0
            Else
                _narx = qiymat
            End If
        End Set
    End Property
End Class

Module Dastur
    Sub Main()
        Dim m As New Mahsulot()

        m.Narx = 15000D
        Console.WriteLine(m.Narx)

        m.Narx = -500D
        Console.WriteLine(m.Narx)
    End Sub
End Module

Public Class Odam
    Public Property Ism As String
    Public Property Familiya As String

    Public ReadOnly Property ToliqIsm As String
        Get
            Return $"{Familiya} {Ism}"
        End Get
    End Property
End Class

Module Dastur
    Sub Main()
        Dim o As New Odam With {.Ism = "Dilnoza", .Familiya = "Yusupova"}
        Console.WriteLine(o.ToliqIsm)
    End Sub
End Module

Public Class Hisoblagich
    Public Shared Soni As Integer = 0
    Public Property Nom As String

    Public Sub New(nom As String)
        Me.Nom = nom
        Soni += 1
    End Sub

    Public Shared Function Tavsif() As String
        Return $"Jami yaratilgan: {Soni}"
    End Function
End Class

Module Dastur
    Sub Main()
        Dim a As New Hisoblagich("birinchi")
        Dim b As New Hisoblagich("ikkinchi")
        Dim c As New Hisoblagich("uchinchi")

        Console.WriteLine(Hisoblagich.Soni)
        Console.WriteLine(Hisoblagich.Tavsif())
        Console.WriteLine(c.Nom)
    End Sub
End Module

Public Class Nuqta
    Public Property X As Integer
    Public Property Y As Integer

    Public Sub New(x As Integer, y As Integer)
        Me.X = x
        Me.Y = y
    End Sub

    Public Overrides Function ToString() As String
        Return $"({X}, {Y})"
    End Function
End Class

Module Dastur
    Sub Main()
        Dim n As New Nuqta(3, 7)
        Console.WriteLine(n)
        Console.WriteLine($"Nuqta: {n}")

        Dim royxat As New List(Of Nuqta) From {
            New Nuqta(1, 1), New Nuqta(2, 4)
        }
        Console.WriteLine(String.Join(" ", royxat))
    End Sub
End Module

Public Class Quti
    Public Property Ichi As String
End Class

Module Dastur
    Sub Main()
        Dim a As New Quti With {.Ichi = "olma"}
        Dim b As Quti = a

        b.Ichi = "anor"

        Console.WriteLine(a.Ichi)
        Console.WriteLine(b.Ichi)
        Console.WriteLine(a Is b)
    End Sub
End Module